FileReferenz Klasse

[amsl]

Hi,
ich möchte die FileReference Klasse benutzen um ein Video von ner website anzubieten. local wenn ich es teste geht es auch. online ruft er auch dialogfenster auf und fragt nach speicherort aber läd nicht runter. benutze ich die klasse falsch? -fehlermeldung gibt es aber keine.

danke für nen hinweis..

on (release) {
	import flash.net.FileReference;
	var listener:Object = new Object();
	listener.onSelect = function(file:FileReference):Void  {
		trace("onSelect: "+file.name);
	};
	listener.onCancel = function(file:FileReference):Void  {
		trace("onCancel");
	};
	listener.onOpen = function(file:FileReference):Void  {
		trace("onOpen: "+file.name);
	};
	listener.onProgress = function(file:FileReference, bytesLoaded:Number, bytesTotal:Number):Void  {
		trace("onProgress with bytesLoaded: "+bytesLoaded+" bytesTotal: "+bytesTotal);
	};
	listener.onComplete = function(file:FileReference):Void  {
		trace("onComplete: "+file.name);
	};
	listener.onIOError = function(file:FileReference):Void  {
		trace("onIOError: "+file.name);
	};
	var fileRef:FileReference = new FileReference();
	fileRef.addListener(listener);
	var url:String = "http://www.meinewebsite.com/Ordner/datei.mpg";
	if (!fileRef.download(url, "datei.mpg")) {
		trace("dialog box failed to open.");
	}
}

[StephanF]

machs mal so, dann sollte das funktionieren:

PHP-Code:

// FileReference-Klasse
//System.security.allowDomain("http://www.funkeundfunke.de");
import flash.net.FileReference;
var downloadDatei:String = "http://www.funkeundfunke.de/html/flash/flvs/rosen.flv";
var downloadName:String = "rosen.flv";
t_txt.text = "Download der Datei: " + downloadName + " ca.500 KB";
// Upload-Listener
var down_listener:Object = new Object();
down_listener.onSelect = function(datei:FileReference):Void  {
    status_txt.text = "Auswahl: " + file.name;
};
down_listener.onCancel = function(datei:FileReference):Void  {
    status_txt.text = "Auswahl abgebrochen!";
};
down_listener.onOpen = function(datei:FileReference):Void  {
    status_txt.text = "Geöffnet: " + datei.name;
};
down_listener.onProgress = function(datei:FileReference, bytesLoaded:Number, bytesTotal:Number):Void  {
    status_txt.text = "Downloadstatus: " + bytesLoaded + " Bytesgesamt: " + bytesTotal;
};

down_listener.onIOError = function(datei:FileReference):Void  {
    status_txt.text = "IO-Fehler: " + datei.name;
};

down_listener.onSecurityError = function(datei:FileReference, fehlermeldung:String):Void  {
    status_txt.text = "Sicherheitsfehler: " + datei.name + " Meldung: " + fehlermeldung;
};

down_listener.onComplete = function(datei:FileReference):Void  {
    status_txt.text = "Download " + datei.name + " erfolgreich!";
};
// FileReference-Objekt
var download_ref:FileReference = new FileReference();

download_ref.addListener(down_listener);

download_btn.onRelease = function() {
    var url_pfad:String = downloadDatei;
    if (!download_ref.download(url_pfad, downloadName)) {
        status_txt.text = "Dialogfenster konnte nicht geöffnet werden!.";
    }
}; 


Das ganze kannst Du Dir hier angucken: Beispiel

[StephanF]

Hats was geholfen