Integrationsproblem Ticker

[carlsson]

Hallo zusammen, folgendes Problem habe ich momentan und komme nicht recht voran...

Beim Einfügen des folgenden Codes in eine bestehende .fla, wird der Ticker zwar angezeigt, füllt aber den gesamten Bereich des Dokumentes von links nach rechts aus.

siehe Beispiel

Wie schaffe ich es aber, das der Ticker nur in einem von mir dafür vorgesehenen, definierten Bereich erscheint ? Evtl. mit einem variablen Textfeld ?, wie aber ist da vorzugehen ?

...wäre über eine kleine Hilfestellung sehr dankbar

System.useCodepage=true;

news = '<font face="Arial" size="10"> tickerinfo </font>'

geschwindigkeit = 1;
x = 200;
y = 475;
tiefe = 1;


createTextField("newstext", tiefe, x, y, 200, 20);
newstext.html = true;
newstext.selectable = false;
newstext.htmlText = news;
newstext.autoSize = "right";

createTextField("newstext2", tiefe1, x, y, 200, 20);
newstext2.html = true;
newstext2.selectable = false;
newstext2.htmlText = news;
newstext2.autoSize = "left";

newstext.setTextFormat(textformat);
newstext2.setTextFormat(textformat);

newstext2._x = newstext._width;

onEnterFrame = function() {
newstext._x -= geschwindigkeit;
newstext2._x -= geschwindigkeit;
if(newstext2._x <= x) {
newstext._x = x;
newstext2._x = newstext._width + x;
}
}

mit einem netten Gruß, der carlsson

[root_alpha]

Hi,

pack doch das ganze in einen MovieClip und gib diesem die entsprechende Größe und Position.

[carlsson]

Hai rooti, schön einmal wieder etwas von Dir zu hören...

Das mit dem MC habe ich bereits versucht, nur hat das irgendwie nicht geklappt.

Einfügen, -neues Symbol, -MC ... nur konnte ich den MC nirgendwo sehen bzw lokalisieren. Habe da denk ich ein Grundsatzproblem.

[root_alpha]

Deinen neu erstellten MC findest du in der Bibliothek des Projektes. Den packst du dann auf die Bühne. Damit du die Größe besser kontrollieren kannst, leg im Mc selbst einen Rahmen an in der passenden Größe und Farbe/ oder Transparenz.

[Wanderratte]

*hüstel* ich mische mich da ungerne ein aaaaaaaber:

System.useCodepage = true;

news = '<font face="Arial" size="10"> Hallo zusammen, folgendes Problem habe ich momentan und komme nicht recht voran... <b>Dann lass mal die Wanderratte dran</b></font>';

geschwindigkeit = 1;
x = 200;
y = 50;
tiefe = 1;
tiefeMaske = 2;
var maske = createEmptyMovieClip("masken_mc", tiefeMaske);
maske._x = x;
maske._y = y;
mLaenge = 400
mHoehe = 100
drawRectangle(maske,mLaenge,mHoehe,0x99FF00,100);
function drawRectangle(target_mc:MovieClip, boxWidth:Number, boxHeight:Number, fillColor:Number, fillAlpha:Number):Void {
    with (target_mc) {
        beginFill(fillColor,fillAlpha);
        moveTo(0,0);
        lineTo(boxWidth,0);
        lineTo(boxWidth,boxHeight);
        lineTo(0,boxHeight);
        lineTo(0,0);
        endFill();
    }
}
var text_mc = createEmptyMovieClip("text_container", tiefe);
text_mc._x = x;
text_mc._y = y;


text_mc.createTextField("newstext",tiefe,x,y,200,20);
text_mc.newstext.html = true;
text_mc.newstext.selectable = false;
text_mc.newstext.htmlText = news;
text_mc.newstext.autoSize = "right";

text_mc.createTextField("newstext2",tiefe1,x,y,200,20);
text_mc.newstext2.html = true;
text_mc.newstext2.selectable = false;
text_mc.newstext2.htmlText = news;
text_mc.newstext2.autoSize = "left";

text_mc.newstext.setTextFormat(textformat);
text_mc.newstext2.setTextFormat(textformat);

text_mc.newstext2._x = text_mc.newstext._width;

text_mc.onEnterFrame = function() {
    this.newstext._x -= geschwindigkeit;
    this.newstext2._x -= geschwindigkeit;
    if (this.newstext2._x<=0) {
        this.newstext._x = x;
        this.newstext2._x = this.newstext._width;
    }
};
text_mc.setMask(maske); 

Nicht vergessen, dass du die Schriftart einbetten muss

[root_alpha]

Na, von der Wanderratte die mal wieder rein schaut, kann man das Verzeihen

Keine Ahnung ob Ihm meine Tips was gebracht haben!, aber mit AS ist es natürlich Eleganter, da bin ich aber schon lange weg von



ps. wie geht`s so ?!

[Wanderratte]

Ne ohne Maske läuft da garnichts, selbst wenn er den mc eine länge mitgibt, geht das Textfeld halt im Minusberreich rein und du siehst es immer noch.

[carlsson]

Hallo zusammen und Euch beiden ersteinmal vielen Dank für Eure Hilfe.
Ich war bis heute beruflich unterwegs und konnte deshalb nicht früher antworten, sorry.

Naja, also bei dem Script von Wanderratte fängt der Text allerdings an sich plötzlich zu überlagern... Mit Änderungen an den Parametern bekomme ich diese "Störung" einfach nicht weg. Habe Da jetzt auch sehr wenig bis gar keine Erfahrung mit der Syntax von AS.... Leider.

Muss denn das script letztendlich in einen Mc rein, wie root alpha ja zuerst meinte ?

[Wanderratte]

upsala, da habe ich eine Abfrage übersehen sie zu überarbeiten.
Nu aber

System.useCodepage = true;

news = '<font face="Arial" size="10"> Hallo zusammen, folgendes Problem habe ich momentan und komme nicht recht voran... <b>Dann lass mal die Wanderratte dran</b></font>';

geschwindigkeit = 1;
x = 200;
y = 50;
//Abstand zwischen den Textfeldern
textAbstand = 100;
tiefe = 1;
tiefeMaske = 2;
var maske = createEmptyMovieClip("masken_mc", tiefeMaske);
maske._x = x;
maske._y = y;
//Länge des Sichtbarenbereiches
mLaenge = 400;
mHoehe = 100;
drawRectangle(maske,mLaenge,mHoehe,0x99FF00,100);
function drawRectangle(target_mc:MovieClip, boxWidth:Number, boxHeight:Number, fillColor:Number, fillAlpha:Number):Void {
    with (target_mc) {
        beginFill(fillColor,fillAlpha);
        moveTo(0,0);
        lineTo(boxWidth,0);
        lineTo(boxWidth,boxHeight);
        lineTo(0,boxHeight);
        lineTo(0,0);
        endFill();
    }
}
var text_mc = createEmptyMovieClip("text_container", tiefe);
text_mc._x = x;
text_mc._y = y;
text_mc.createTextField("newstext",tiefe,x,y,200,20);
text_mc.newstext.html = true;
text_mc.newstext.selectable = false;
text_mc.newstext.htmlText = news;
text_mc.newstext.autoSize = "right";

text_mc.createTextField("newstext2",tiefe1,x,y,200,20);
text_mc.newstext2.html = true;
text_mc.newstext2.selectable = false;
text_mc.newstext2.htmlText = news;
text_mc.newstext2.autoSize = "left";

text_mc.newstext.setTextFormat(textformat);
text_mc.newstext2.setTextFormat(textformat);

text_mc.newstext2._x = text_mc.newstext._x+text_mc.newstext._width+textAbstand;

text_mc.onEnterFrame = function() {
    this.newstext._x -= geschwindigkeit;
    this.newstext2._x -= geschwindigkeit;
    if (this.newstext._x+this.newstext._width<0) {
        this.newstext._x = this.newstext2._x+this.newstext2._width+textAbstand;

    }
    if (this.newstext2._x+this.newstext2._width<=0) {
        this.newstext2._x = this.newstext._x+this.newstext._width+textAbstand;


    }
};
text_mc.setMask(maske); 

[carlsson]

Wuff, Wanderratte Du bist ein Genie

jetzt die Syntax etwas zu hinterfragen wäre etwas zuviel verlangt......, grmmmpfffll
Aber wie komme ich da etwas rein ?


Vielen Dank für Deine Hilfe

[Wanderratte]

Eigentlich durch F1 einfach den Befehl markieren und F1 drücken.
Der Ablauf ist folgender:
Ich erstelle einen MC (createEmptyMovieClip) für die Maske
Danach zeichne ich ein Rechteck mit Hilfe der Funktion drawRectangle
im Anschluss wird ein leerer MC erstellt, in dem die Textfelder erstellt werden

variablen
x,y = die Posiition von links und oben gesehen

//Abstand zwischen den Textfeldern
textAbstand = 100; 

mLaenge ist für den sichtbaren bereich
//Länge des Sichtbarenbereiches

mLaenge = 400; 

mHoehe ist relativ, lieber etwas mehr als zu wenig. Du siehst das eh nicht.

mHoehe = 100; 

Positioniert die Textfelder

text_mc.newstext2._x = text_mc.newstext._x+text_mc.newstext._width+textAbstand; 

Diese Funktion fragt immer die Postion der Textfelder ab

text_mc.onEnterFrame = function() {
    this.newstext._x -= geschwindigkeit;
    this.newstext2._x -= geschwindigkeit;
    if (this.newstext._x+this.newstext._width<0) {
        this.newstext._x = this.newstext2._x+this.newstext2._width+textAbstand;

    }
    if (this.newstext2._x+this.newstext2._width<=0) {
        this.newstext2._x = this.newstext._x+this.newstext._width+textAbstand;


    }
}; 

Dieser Befehl setzt die Maske

text_mc.setMask(maske); 

Das wäre es so im Groben, die Feinheiten finde mal mit f1 raus, dass würde sonst ausufern

EDIT

kommentiere doch die Zeile mal aus: text_mc.setMask(maske);

[carlsson]

Jetzt weiß ich wirklich nicht mehr wie ich dir dafür danken soll....

[Wanderratte]

Wenn ich Gemein wäre, würde ich mal sagen gucke dir mal meine Signatur genau an
Aber ich bin ja nicht gemein, eine freundliche Bewertung tut es auch