actionscript: Parameterübergabe und onEnterFrame

[T:-)M]

Hallo,

ich möchte von der Hauptzeitleiste aus einen Movieclip (test_mc) über einen Button (start_btn) steuern. Das klappt auch so verschachtelt.

_root.start_btn.onRelease = function () {
endX= _root.test_mc._x+200;
_root.test_mc.onEnterFrame = function() {
div=5; // groesser=schneller
_root.test_mc._x += (endX-_root.test_mc._x)/div;
}
}

Nun möchte ich diese Verschachtelung aufspalten und habe folgendes probiert:

_root.test_mc.onEnterFrame = function(endX:Number, div:Number) {
_root.test_mc._x += (endX-_root.test_mc._x)/div;
trace(endX);
}

_root.start_btn.onRelease = function () {
endPunktX= _root.test_mc._x+200;
_root.test_mc.onEnterFrame(endPunktX, 5);
}

Das Problem ist die Parameterübergabe beim Aufruf der Funktion.
Da ich onEnterFrame habe, wird jedesmal wieder der gleiche Wert übernommen, so dass er sich in der Funktion nicht verändern kann.
Ich hoffe, ich habe mich einigermaßen verständlich ausgedrückt...

Weiß von Euch eventuell jemand einen Lösungsansatz?

Vielen Dank im Voraus.

Gruß

T:-)M

[Wanderratte]

Hallo,

versuche es doch mal so:

PHP-Code:

MovieClip.prototype.bewegung = function (endX:Number, div:Number) {
    delete this.onEnterFrame;
    this.onEnterFrame = function () {
        this._x += (endX - this._x) / div;
        trace (endX);
    };
};
_root.start_btn.onRelease = function () {
    endPunktX = _root.test_mc._x + 200;
    _root.test_mc.bewegung (endPunktX,5);
}; 


[T:-)M]

Hallo Wanderratte,

ziemlich schräge Lösung - es funktioniert. Habe nur leider wieder eine verschachtelte Lösung, die eigentlich auch nicht kürzer ist.

Gruß

T:-)M

[Wanderratte]

Noch kürzer ????
Meine Lösung kannst du übrigens auf x Objekte anwenden ohne das du am laufenden Band neue onEnterFrame erstellen musst. Aber okay, probiere das hier doch mal aus

PHP-Code:

_root.test_mc.endX = 200;
_root.test_mc.div = 5;
_root.test_mc.onEnterFrame = function () {
    this._x += (this.endX - this._x) / this.div;
    trace (endX);

};
_root.start_btn.onRelease = function () {
    _root.test_mc.endX = _root.test_mc._x + 200;
    _root.test_mc.div = 5;
}; 


[T:-)M]

Hallo Wanderratte,

der läuft auch ohne Button :-D
... ich glaub, da finde ich die Lösung drüber doch besser.

Gruß

T:-)M

[Wanderratte]

wenn er erst laufen soll, wenn der button geklickt wird, dann nimm doch mal diese Zeile:

PHP-Code:

_root.test_mc.endX = _root.test_mc._x; 


Naja, es gibt x Wege nach Rom aber die edlere ist halt der Prototype. Die andere Frage ist auch immer was du genau vorhast bzw was du alles bezwecken willst

[T:-)M]

... hmm wahrscheinlich ist das mit dem Prototype der beste Weg.
Ist nur ungewohnt einen Movieclip zu erzeugen und die onEnterFrame gleich wieder zu löschen.

Ich möchte es für eine Navi verwenden. Der Inhalt verschiebt sich hinter einer Maske - hier nur in x-Richtung jeweils ein Stückchen weiter.
Aber ich möchte es auch für völlig freie x- und y- Koordinaten verwenden - deshalb die Idee die Werte über eine Button zu übergeben.

[Wanderratte]

Sag das doch gleich
gucke mal hier, aber kürzer geht es nun wirklich nicht mehr. Glaube ich wenigstens
Flash8 und AS2 sind aber nötig

PHP-Code:

import mx.transitions.Tween;
import mx.transitions.easing.*;

function tweenX (ziel:Number,target:MovieClip) {
    new mx.transitions.Tween (target, "_x", Regular.easeOut, target._x, ziel, 1, true);
}

_root.start_btn.onRelease = function () {
    tweenX (test_mc._x +  200,test_mc);
}; 


[T:-)M]

.. die easing transitions kann man natürlich auch nehmen
- das ist wirklich am Kürzesten.

Nochmal Danke,

Gruß

T:-)M