Dateiupload mit PHP (Flashformular)

[maxi89]

Hallo zusammen,

ich weiß, solche oder ähnliche Fragen gab es hier schonmal, aber so richtig gefunden, was ich gesucht habe, habe ich nicht.
Es geht darum, dass auf einen Webserver über ein PHP-Script teils bis zu 100 MB große (einzelne) Dateien hochgeladen werden sollen. Weil aber spätestens bei einer solchen Größe längere Zeit scheinbar nichts passiert, sollte da ein Ladebalken hin, damit der User sieht, wie weit es voran geht.
Ich habe dabei an ein Uploadfeld in Flash gedacht, wie es Youtube verwendet, aber da ich absolut kein Flashexperte bin, habe ich bei Google gesucht und da nur immer so Riesendinger (komplett für diese Zwecke überdimensioniert) gefunden habe, wollte ich mal Fragen, ob mir hier jemand etwas empfehlen kann.
Möglichst so anpassbar, dass ich das bisherige Script weiternutzen kann, bzw. nur minimale Anpassungen notwendig sind.

Danke schonmal

[StephanF]

Möglichst so anpassbar, dass ich das bisherige Script weiternutzen kann, bzw. nur minimale Anpassungen notwendig sind.

Da bleibt ja wieder nur die Glaskugel. Was sind den deine bisherigen Scripte und wie sehen die aus?

[maxi89]

Ups, entschuldigung

Das Uploadscript ist relativ simpel gestrickt, hier der wesentliche Teil:

PHP-Code:

<form name="upload" enctype="multipart/form-data" action="up.php">
<input type="file" name ="upload"><br>
<input type="submit" name="subm" value="Hochladen">
</form>
....
<?php
$username = $_SERVER['PHP_AUTH_USER'];
$datei = $_FILES['upload']['name'];
move_uploaded_file($_FILES['upload']['tmp_name'], $username.$datei;
?>

[StephanF]

Probier mal folgendes:

PHP-Code:

System.useCodepage = true;
// FileReference-Klasse
import flash.net.FileReference;

//Ladebalken am Anfang unsichtbar
loader_mc._visible = false;
// Liste mit zugelassenden Bildformaten
var dateitypen:Array = new Array();
var bildformate:Object = new Object();
//Erlaubte Dateitypen und Bezeichnungen
bildformate.description = "Dateiformate (*.jpg,*.flv,*.mov,*.mpg, *.avi, *.wmv)";
//bildformate.description = "Datei (*.*)";
bildformate.extension = "*.jpg; *.flv; *.mov; *.mpg; *.avi; *.wmv;";
//bildformate.extension = "*.*;";
dateitypen.push(bildformate);
// Upload-Listener
var up_listener:Object = new Object();
/*
Dialogfenster öffnen
*/
up_listener.onSelect = function(datei:FileReference):Void  {
    if (!datei.upload("upload.php?"+new Date().getTime()+"&vonFlash=1")) {
        status_txt.text = "Upload Dialogfenster konnte nicht geöffnet werden!.";
    }
};
/*
Wenn Auswahl abgebrochen
*/
up_listener.onCancel = function(datei:FileReference):Void  {
    status_txt.text = "Auswahl abgebrochen!";
};
/*
Wird aufgerufen, wenn der Upload bzw. Download einer Datei 
gestartet wird.
*/
up_listener.onOpen = function(datei:FileReference):Void  {
    status_txt.text = "Geöffnet: "+datei.name;
};
/*
Wird regelmäßig während des Upload- bzw. Download-Vorgangs 
aufgerufen.
*/
up_listener.onProgress = function(datei:FileReference, bytesLoaded:Number, bytesTotal:Number):Void  {
    status_txt.text = "Uploadstatus: "+bytesLoaded+" Bytesgesamt: "+bytesTotal;
    g = Math.round(bytesLoaded/1024);
    t = Math.round(bytesTotal/1024);
    status_txt.text = "Status: "+g+"KB von: "+t+"KB geladen";
    prozent = int(bytesLoaded*100/bytesTotal);
    p_txt.text = prozent+" %";
    loader_mc._visible = true;
    setProperty("loader_mc", _xscale, prozent);
};
/*
Wird aufgerufen, wenn ein Upload wegen eines HTTP-Fehlers 
abgebrochen wird. 
*/
up_listener.onHTTPError = function(datei:FileReference):Void  {
    status_txt.text = "HTTP-Fehler: "+datei.name;
};
/*
Wird aufgerufen, wenn während des Lese-, Schreib- oder 
Übertragungsvorgangs der Datei ein Eingabe/Ausgabe-Fehler 
auftritt.
*/
up_listener.onIOError = function(datei:FileReference):Void  {
    status_txt.text = "IO-Fehler: "+datei.name;
};
/*
Wird aufgerufen wenn ein Sicherheitsfehler während 
der Übertragung auftritt.
*/
up_listener.onSecurityError = function(datei:FileReference, fehlermeldung:String):Void  {
    status_txt.text = "Sicherheitsfehler: "+datei.name+" Meldung: "+fehlermeldung;
};

up_listener.onComplete = function(datei:FileReference):Void  {
    status_txt.text = "Upload "+datei.name+" erfolgreich!";
};
// FileReference-Objekt
var upload_ref:FileReference = new FileReference();
// FileReference-Objekt wird der Listener up_listener
// mit sämtlichen Ereignisprozeduren zugewiesen
upload_ref.addListener(up_listener);
// Upload-Schalter
upload_btn.onRelease = function() {
    upload_ref.browse(dateitypen);
};
// 


und die PHP-Datei:

PHP-Code:

$pfad = 'copy/';
$datei = $pfad . basename($_FILES['Filedata']['name']);
@move_uploaded_file($_FILES['Filedata']['tmp_name'], $datei);