Tischkarten erstellen?

[kojote81]

Hallo

ich hab ein Probelm, ich habe Tischkarten gestaltet. Erst eine, und dann habe ich nach Optionen gesucht, dass man Automatisch die Vorlage nehmen kann und nur den Namen ändert.. vergebens.. dann habe ich alle Tischkarten erstellt und versucht mit der Option Bildpaket zu drucken, leider gibt es da nur 4 Karten auf einer Seite oder 8.. ich brauch aber 6 ( eine Karte ist 10x10cm).

Wie würdet ihr sowas anfangen.. könnt ihr mir helfen?

Gruss Anne

[satre]

Zunächst mal ist 10 mal 10 eine sehr ungünstige Größe, weil A4 genau 210*297mm groß ist. Deswegen kannst du die 6er Version abhaken, weils nach unten nicht passt und du zur Seite einen extrem kleinen Verschnitt hast.

Ich würde vorschlagen eine Vorlage mit 9*9cm oder 8*8cm zu erstellen und diese Später 6 mal als Ebenenordner in ein neues A4 Photoshopdokument (am besten mit cm-Raster) einzufügen. Die Namen kannst du dann immer noch ändern.

[kojote81]

Danke für die schnelle Antwort!

Dass ist ja mist, ich dachte man könnte ne neue Druckvorlage oder sowas erstellen. Übrigens dass mit dem Format hatte ich schon gemerkt.. hab die Teile 10 x 9 gemacht.
Also kann ich gleich die fertigen karten in ein Dokument eifügen!

Gruss Anne

[hotschen]

Genau vor dem Problem stand ich vor kurzem auch. Habe mir dazu ein Script in VBS gecodet, Welches die Namen aus einer Excel oder Textdatei liest und die Karten automatisch auf ein A4 Blatt anordnet. Werd heut Nachmittag mal schauen, ob ich es noch finde.

[satre]

hab die Teile 10 x 9 gemacht.

Das ist immer noch ne verflixt kleine Toleranzgrenze; 5mm Rechts und Links. Ist es bei der Gestaltung nicht mehr möglich, die Karte auf 9*9cm zu bringen? Denn dann wärst du Verschnittsmäßig auf der Sicheren Seite.

Also kann ich gleich die fertigen karten in ein Dokument eifügen!
Gruss Anne

Wo ist das Problem?
Wenn du eine Karte mit allen Ebenen in einem Ordner zusammenfasst, kannst du diese schön in ein A4-Dokument reinziehen und sauber Anordnen. Die Textebenen lassen sich weiterhin bearbeiten. Somit hast du ein Template für jeweils sechs Karten.

Um wie viele Namen gehts denn?

[kojote81]

wie fasse ich denn die Ebenen in einem Ordner zusammen, ohne alles auf eine Ebene zu reduzieren?

Es handelt sich um 38 Namen, und wie gesagt hab ich die Teile schon fertig in 10x9, aber dass ist ja kein Problem, beim drucken kann man dass ja anpassen wenn es ein Dokument ist.

[kojote81]

Genau vor dem Problem stand ich vor kurzem auch. Habe mir dazu ein Script in VBS gecodet, Welches die Namen aus einer Excel oder Textdatei liest und die Karten automatisch auf ein A4 Blatt anordnet. Werd heut Nachmittag mal schauen, ob ich es noch finde.

das klingt verdammt gut

[satre]

wie fasse ich denn die Ebenen in einem Ordner zusammen, ohne alles auf eine Ebene zu reduzieren?

Siehe Anhang.

[kojote81]

Siehe Anhang.

suuuper, danke

[hotschen]

Ich weiß nicht, ob noch Interesse besteht, aber vielleicht kann der eine oder andere das Script ja auch mal gebrauchen.
Voraussetzung:
-PS CS/CS2 oder PS7 mit installiertem Scriptplugin (kostenlos)
-eine geöffnete Datei einer Tischkarte mit einer Textebene
-eine Textdatei mit den einzusetzenden Namen

Kopiere folgenden Code in eine neue Textdatei und nenne sie "Tischkarten.vbs". Passe ggf die Pfade und anderen Einstellungen deinen Wünschen an und starte die die Datei mit Doppelklick.

Dim fso, datei,Namen() 
Dim appref,quellbild,zielbild,strtRulerUnits, strtTypeUnits
Dim dpi,anzseiten, anz, Spalten,  karte_y, karte_x,zaehler,Rand,dateipfad
Dim speichern, Speicherpfad, schliessen, Schnittlinie

'****Eingaben*******

dpi = 300			'DPI für Zieldatei
Rand=50				'Oberer Rand in Pixel
dateipfad="namen.txt" 		'Dateipfad zur Textdatei mit den Namen
Schnittlinie="j"		'Schnittlinien hinzufügen? "j" oder "n"

speichern="j"			'speichern der erstellten Dateien? "j" oder "n"
Speicherpfad="c:\"		'Speicherpfad für erstellte Dateien
schliessen="n"			'Erstellte Dateien schliessen? "j"oder "n"

'*******************


Set appref = CreateObject("Photoshop.Application")
strtRulerUnits = appRef.Preferences.RulerUnits
strtTypeUnits = appRef.Preferences.TypeUnits
appRef.Preferences.RulerUnits = 1
appRef.Preferences.TypeUnits = 1

NamenEinlesen

Set strokecolor = CreateObject("Photoshop.SolidColor")
With strokecolor
    .CMYK.Cyan = 0
    .CMYK.Magenta = 0
    .CMYK.Yellow = 0
    .CMYK.Black = 100
End With
If appref.Documents.Count=0 Then 
	MsgBox "Erst eine Datei öffnen! Danach Script erneut ausführen."
	WScript.Quit
End If
Set quellbild = appRef.ActiveDocument
neuesblatt

multi = quellbild.Height / quellbild.Width


karte_x = quellbild.Width
karte_y = quellbild.Height
If karte_x > 21 / 2.54 * dpi OR karte_y * 2 > 29.7 / 2.54 * dpi Then
    MsgBox "Die Karte ist zu groß für A4!"
    WScript.quit
End If

deltx = 0
delty = Rand
erstes = True
Spalten = 21 / 2.54 * dpi \ (karte_x - 1)

For i = 0 To zaehler
    appref.ActiveDocument = quellbild
    quellbild.ArtLayers(1).TextItem.Contents = Namen(i)
    quellbild.Selection.SelectAll
    quellbild.Selection.Copy True
    appref.ActiveDocument = zielbild

    Select Case Spalten
    Case 2
        zielbild.Selection.Select Array( _
            Array(zielbild.Width / 2 - karte_x + deltx, delty), _
            Array(zielbild.Width / 2 + deltx, delty), _
            Array(zielbild.Width / 2 + deltx, karte_y + delty), _
            Array(zielbild.Width / 2 - karte_x + deltx, karte_y + delty))
    Case 1
        zielbild.Selection.Select Array( _
            Array(zielbild.Width / 2 - karte_x / 2 + deltx, delty), _
            Array(zielbild.Width / 2 + karte_x / 2 + deltx, delty), _
            Array(zielbild.Width / 2 + karte_x / 2 + deltx, karte_y + delty), _
            Array(zielbild.Width / 2 - karte_x / 2 + deltx, karte_y + delty))
    Case Else
        zielbild.Selection.Select Array( _
            Array(zielbild.Width / 2 - karte_x * Spalten / 2 + deltx, delty), _
            Array(zielbild.Width / 2 - karte_x * (Spalten - 2) / 2 + deltx, delty), _
            Array(zielbild.Width / 2 - karte_x * (Spalten - 2) / 2 + deltx, karte_y + delty), _
            Array(zielbild.Width / 2 - karte_x * Spalten / 2 + deltx, karte_y + delty))
    End Select
    If Schnittlinie="j" Then zielbild.Selection.Stroke strokecolor,1, 3
    delty = delty + karte_y

    zielbild.Paste
    zielbild.ArtLayers(1).Merge

    If delty + karte_y > zielbild.Height AND deltx + 2 * karte_x > zielbild.Width AND i<>zaehler Then
        If speichern="j" Then 
        	zielbild.saveas Speicherpfad & zielbild.name
        	If schliessen="j" Then zielbild.close
        End If
        neuesblatt
        deltx = 0
        delty = Rand
    Else
    	If delty + karte_y > zielbild.Height Then
     	   delty = Rand
     	   deltx = karte_x + deltx
   		 End If
 	End If
Next 
If speichern="j" Then 
	zielbild.saveas Speicherpfad & zielbild.name
	If schliessen="j" Then zielbild.close
End If
appref.Preferences.RulerUnits = strtRulerUnits
appref.Preferences.TypeUnits = strtTypeUnits

Sub neuesblatt()
    anzseiten = anzseiten + 1
    Set zielbild = appref.Documents.Add(21 / 2.54 * dpi, 29.7 / 2.54 * dpi, dpi, "Tischkarten Seite " & anzseiten & ".psd")
End Sub

Sub NamenEinlesen()
	zaehler=0
	anzseiten=0
	Set fso = CreateObject("Scripting.FileSystemObject")
	Set datei = fso.opentextfile(dateipfad,1)
	
	Do While Not datei.AtEndOfStream
		Redim Preserve Namen(zaehler)
		Namen(zaehler)=datei.readline
		zaehler=zaehler+1
	Loop
	zaehler=zaehler-1
	datei.close 
End Sub

Im Anhang nochmal die vbs- und eine Bsp.Datei

[littleb]

Hallo erstmal alle zusammen

Bin völliger Anfänger aber ich muss kommendes WE für einen Ball die Tischkarterl machen. Habe das script ausprobiert bekomme aber einen Fehler: Fehler in Zeile 21 ..... Preferences.

Voraussetzung:
-PS CS/CS2 oder PS7 mit installiertem Scriptplugin (kostenlos)

1.Wie weis ich ob ich dieses Scriptplugin installiert habe oder wo bekomme ich es her.

2. wie ändere ich den Hintergrund ???

Bitte nicht verbal erschlagen für die blöden Anfängerfragen

Bernhard

[hotschen]

Das Scriptplugin bekommst du hier.
Erstelle einfach eine Tischkarte in beliebiger Grösse (oder nimm die Beispieldatei und verändere sie). Achte darauf, dass die gewünschte Ausgabe grösse für 300dpi passt. Bsp: Sollen die Karten 9x9cm sein (sie werden ja noch gefaltet), benötigst du bei 300dpi 1063x1063px.
Für den Hintergrund kannst du ein beliebiges Bild einsetzen und anschliessend eine Textebene daüber positionieren.
Pfade im Script anpassen, Script starten, Kaffe trinken, fertig.

Bei Problemen einfach nochmal fragen.

[littleb]

Danke für die rasche antwort

Habe mir eine eigene Vorlage erstellt und das Skrip läuft aber noch eine Frage:
Wie und wo kann ich die Schriftgrösse und -art im VB Script ändern???


Danke im Voraus

Bernhard

[hotschen]

Entweder du ersetzt diese Zeile

    quellbild.ArtLayers(1).TextItem.Contents = Namen(i)

durch folgendes:

    With quellbild.ArtLayers(1).TextItem
    	.Contents = Namen(i)
    	.Font = "Arial" 
    	.Size = 24
    End With

oder einfacher: Du stellst die gewünschte Schriftart und -größe vorher für die Textebene ein.

[littleb]

DANKE

Hat super funktioniert *Daumen hoch*
Wenn du mal in der Gegend bist hast ein Bier gut bei mir :-))
Bernhard