Suche Branding/Watermark-Tool für Photoshop

[Ducatisti]

Ich suche dringend nach einem Branding/Watermarkting-Tool für PS.

Mir geht es hauptsächlich darum, das ich 100 Pix und mehr (Hoch- und Querformat, verschiedene Grössen) mit einem Logo versehen will. Die üblichen Freeware und Shareproramme aber nicht die Photoshop Features wie Schattierung, variable Transparenz usw. zu bieten.

Habt Ihr eine Lösung für mich.

VielenDank
ducatisti

[Ducatisti]

Sicherlich habe ich mit denen schon gearbeitet. Doch funktioniert das auch, wenn ich ein Branding immer auf der gleichen Stelle bei Hoch- und Querformatbildern unterbringen will? Und was ist wenn 25 Pix 800 x 600 haben und 30 Pix 1024 x 768 usw. Dann ist es am Ende doch unterschiedlich gross. Das sollte aber nicht so sein ?!?

[Ducatisti]

Danke koi-sh für die Infos.

Ja zentriert ist ja ganz nett, aber rechts/links/oben/unten, da wird es schon schwieriger. Und wie gesagt das Logo soll immer die Gleiche grösse haben, bei unterschiedlichen Bildgrössen kannst Du das vergessen.

Sicherlich macht Versuch klug, nur nach mißglückten Versuchen macht nachfragen klüger

[Thomas]

ein paar Threads mit hilfreichen Tools & Tipps zum Thema:

http://www.traum-projekt.com/forum/7...=wasserzeichen
http://www.traum-projekt.com/forum/2...ight=watermark
http://www.traum-projekt.com/forum/7...=wasserzeichen

[Alexander Groß]

Und von mir auch noch ein tolles Beispiel:

http://av.adobe.com/russellbrown/BrandingSM.mov

In Farbe und auch in bunt

Alex

[hotschen]

Ich hab dazu vor einiger Zeit mal ein VB-Script(läuft also nur unter windows ab PS7) gebastelt. Zu finden hier.
Bei Bedarf poste ich morgen auch noch eine erweiterte Version dazu (hab ich nicht hier auf dem Rechner).

Edit: Hatte es doch noch noch hier: (Anleitung findest du in o.g. Post)

'*************************************************************************
'   Voraussetzung: 
'***   -PS CS(2) oder PS 7 mit installiertem Scriptunterstützungsplugin
'***   -Windows als Plattform, da ein Mac leider mit VBS nicht klar kommt

'   Beschreibung:   
'***   -Zuerst die Pfade und Werte im "Eingabebereich" anpassen.
'***   -Die Ränder beziehen sich immer auf die gewählte Referenzseite (wird
'***    per Inputbox abgefragt).
'***   -Anschliessend die Datei speichern und die Endung von 'txt' in 'vbs'
'***    umbenennen.
'***   -Ihr könnt nun einfach Dateien per Drag'nDrop auf das Script ziehen.
'***    Wird das Script per Doppelklick gestartet, muss der Pfad der zu
'***    bearbeitenden Bilder angegeben werden. Photoshop wird, falls noch 
'***    nicht geschehen, automatisch gestartet.
'*************************************************************************

Option Explicit
Dim appref, objShell, docref, strtRulerUnits, SaveOptions
Dim	datei, logo,i, rand_x, rand_y, Logopfad,qualitaet,quellpfad
Dim	fso, c, speichern_als,speicherpfad,datei2,zaehler,position, x1, x2, y1, y2

'*********************************************************************
'*********Anfang Eingabebereich***************************************

Logopfad="D:\temp\logo.jpg"	'Pfad zur Logodatei
rand_x=50			'Logoabstand vom vertikalen Bezugsrandand in Pixel
rand_y=50			'Logoabstand vom horizontalen Bezugsrandand in Pixel
speichern_als="jpg"		'in die Anführungszeichen entweder jpg oder psd eintragen
qualitaet=8			'Speicherqualitaet für jpg angeben (1..12)
quellpfad="D:\temp2"	'Wenn keine Bilder per Drag'nDrop auf das Script gezogen werden, werden alle Bilder aus diesem Ordner genutzt

'Achtung! Hier den Speicherpfad angeben. Ohne Angabe werden die Bilder im Quellordner gespeichert und überschrieben
speicherpfad=""		'Beispiel: speicherpfad="C:\temp" oder speicherpfad=""		

'*********Ende Eingabebereich*****************************************
'*********************************************************************

Set objShell = WScript.CreateObject("WScript.Shell")
Set appref = CreateObject("Photoshop.Application")
Set logo = appref.Open (Logopfad)
if speichern_als="jpg" Then
	Set SaveOptions= CreateObject("Photoshop.JPEGSaveOptions") 
	SaveOptions.Quality =qualitaet
Else
	Set SaveOptions= CreateObject("Photoshop.PhotoshopSaveOptions")
End If
Do 
	position=InputBox ("Position eingeben:" & chr(13) & "	ur 	- für unten rechts" & Chr(13) & "	um 	- für unten mitte" _
											& Chr(13) & "	ul 	- für unten links" & Chr(13) & "	or 	- für oben rechts" _
											& Chr(13) & "	om 	- für oben mitte" & Chr(13) & "	ol 	- für oben links" _
											, "Referenzseite","ur")
Loop While pruefung(position)=False
	
strtRulerUnits = appRef.Preferences.RulerUnits
appref.Preferences.RulerUnits = 1
logo.Selection.selectall
logo.Selection.copy
zaehler=0
If WScript.Arguments.count<>0 Then 
	For i=0 To WScript.Arguments.count-1
		datei= wscript.arguments.item(i)
		Set docref=appref.open (datei)
		datei2=datei
		logoeinfuegen
		zaehler=zaehler+1
	Next
Else
	Set fso = CreateObject("Scripting.FileSystemObject") 
	Set datei=fso.getfolder (quellpfad)
	For Each c In datei.Files
		Set docref=appref.Open (c.Path)
		datei2=c.path
		logoeinfuegen
		zaehler=zaehler+1
	Next
End If

sub logoeinfuegen()
	Select Case position
		Case "ur"
			x1=docref.Width -rand_x-logo.Width 
			y1=docref.Height - logo.Height -rand_y
			x2=x1+logo.Width 
			y2=y1+logo.Height 
		Case "um"
			x1=docref.Width/2 -logo.Width /2
			y1=docref.Height - logo.Height -rand_y
			x2=x1+logo.Width 
			y2=y1+logo.Height
		Case "ul"
			x1=rand_x
			y1=docref.Height - logo.Height -rand_y
			x2=x1+logo.Width 
			y2=y1+logo.Height
		Case "or"
			x1=docref.Width -rand_x-logo.Width 
			y1=rand_y
			x2=x1+logo.Width 
			y2=y1+logo.Height 
		Case "om"
			x1=(docref.Width -logo.Width )/2
			y1=rand_y
			x2=x1+logo.Width 
			y2=y1+logo.Height
		Case "ol"
			x1=rand_x
			y1=rand_y
			x2=x1+logo.Width 
			y1=y1+logo.Height
	End Select	
	docref.Selection.Select Array(Array(x1 , y1), Array(x2, y1), Array(x2, y2), Array(x1 , y2)), 1, 0, False
	docref.Paste True
	if speichern_als="jpg" Then docref.MergeVisibleLayers 
	If speicherpfad<>"" Then datei=speicherpfad Else datei=datei2
	docref.Saveas datei,SaveOptions, False
	docref.close
End Sub

logo.Close 
appref.Preferences.RulerUnits = strtRulerUnits	
Select Case zaehler
	Case 0
		MsgBox "Es wurden keine Bilder gefunden. Falscher Pfad angegeben?"
	Case 1
		MsgBox "Das Logo wurde in 1 Bild eingefügt." 
	Case 2
		MsgBox "Das Logo wurde in " & zaehler & " Bilder eingefügt." 		
End Select

Function pruefung(position)
Select Case position
	Case "ur"
			pruefung=True
		Case "um"
			pruefung=True
		Case "ul"
			pruefung=True
		Case "or"
			pruefung=True
		Case "om"
			pruefung=True
		Case "ol"
			pruefung=True
		Case 0
			WScript.quit
		Case Else 
			MsgBox "Ungültige Eingabe"
			pruefung=False
	End Select	
End Function

[Ducatisti]

@Alle -> Danke

Ihr habt mir sehr geholfen. Am Besten finde ich jedoch den Film, der erklärt genau das, wonach ich gesucht habe.

Auch die anderen Infos werde ich mir gleichmal zu Gemüte führen.

@hotschen

Was ist das mit dem VBScript, was muß man da tun ?

Gruß
ducatisti

[hotschen]

kopiere folgenden Code in eine neue Textdatei, passe oben die Angaben deinen Wünschen an und speichere sie als "logo.vbs" ab. Nun einfach eine beliebige Anzahl von Bildern per Drag'n'Drop auf das Script ziehen und zurücklehnen.

Alternativ kannst du auch den Quellordner angeben. Der Eingabebereich ansonsten ist selbsterklärend.

[Alexander Groß]

hotschen ist unser Scriptgott

Alex

[hotschen]

lol...so würd ich das nun nicht ausdrücken. Scripten mit PS macht einfach Spass. Getreu nach dem Motto: Nichts ist unmöglich mit PS!
Nur am Script "Mache_schönes_Bild.vbs" verzweifle ich z.Z. Wobei "Schönes Bild" ja eigentlich auch ne Beleidigung ist. (Siehe hier.)