[MX 2004] und noch ein Menü

[Wanderratte]

Hallo,
Ich habe hier ein Menü für euch, welches unter anderen sich den derzeit aktiven Button merkt.
Desweiteren hat das Menü ein Farbübergang, beim onRollOver, onRelease usw.
Um das Menü für eure Zwecke umzubauen, solltet ihr euch schon ein wenig mit den folgenden Punkte befasst haben:

• Arrays
• Switch/ Case - Anweisung
• Schleifen

Fragen zu dem Menü könnt ihr hier in diesem Thread stellen

Und zum guten Schluß:
Wie immer ich beantworte keine Fragen per Mail oder PN, dafür ist das Forum da !

[Wanderratte]

So und hier gibt es noch eine kleine Erweiterung, damit ist der erste Link aktiviert und auch der Befehl für den Button wird ausgeführt.

PHP-Code:

/* CopyRight by Ralf Berg*/
/*info@creativer.de
/*www.creativer.de */
/**************Deklaration der Variablen *****************/
//Buttonanzahl
var btAnz:Number = 5;
//für den aktiven Button
var btAktiv:MovieClip;
//Beispielarray, was der einzelne Button machen soll
var befehlArray:Array = new Array (["goto", 2], ["lade", "info.swf"], ["neueSeite", "http://www.creativer.de"], ["neuerSound", "sound"], ["neuesBild", "deinBild.jpg"]);
/********* Ende der Deklaration *************/
//
//
//
/************ Beispiel Funktion für die unterschiedlichen Buttonbefehle ****************/
function ausfuehren (i) {
    switch (befehlArray[i][0]) {
        case "goto" :
            //_root.gotoAndPlay (befehlArray[i][1]);
            break;
        case "lade" :
            //_root.loadMovie (befehlArray[i][1]);
            break;
        case "neueSeite" :
            getURL (befehlArray[i][1], "_self");
            break;
        case "neuerSound" :
            //_root.attachSound (befehlArray[i][1]);
            break;
        case "neuesBild" :
            //_root.loadMovie (befehlArray[i][1]);
            break;
    }
}
/********** ENDE ****************/
//
//
//
/********** Prototypen für die Animationen ****************/
MovieClip.prototype.drueber = function () {
    if (this._currentframe < this._totalframes) {
        this.nextFrame ();
    } else {
        delete this.onEnterFrame;
    }
};
MovieClip.prototype.aussen = function () {
    if (this._currentframe > 1) {
        this.prevFrame ();
    } else {
        delete this.onEnterFrame;
    }
};
/*************Prototype Ende**********************/
//
//
//
/********Funktionen für die Button **************/
//Funktionen für onRollOver,onRollOut und onReleaseOutside
over = function () {
    this.onEnterFrame = drueber;
};
out = function () {
    if (this != btAktiv) {
        this.onEnterFrame = aussen;
    }
};
//Funktion für die onReleaseanweisung
release = function () {
    btAktiv.onEnterFrame = aussen;
    this.onEnterFrame = drueber;
    ausfuehren (this.befehl);
    btAktiv = this;
};
/************** Ende Buttonfunktionen *************/
//
//
//
/********Zuweisung des Buttoninhaltes und der Befehle**********/
for (var i = 0; i < btAnz; i++) {
    var obj = this[i + "_bt"];
    obj.befehl = i;
    obj.inhalt_txt.text = befehlArray[i][0];
    obj.onRollOver = over;
    obj.onRollOut = obj.onReleaseOutside = out;
    obj.onRelease = release;
}
/************** Ende der Zuweisung ********************/
function init () {
    var obj = this[0 + "_bt"];
    ausfuehren (obj.befehl);
    obj.onEnterFrame = drueber;
    btAktiv = obj;
}
init ();