PHP mit Flash aufrufen bzw. ausführen

[oller_24]

Mein Problem ist dass ich mir Flash PHP scripte nicht aufrufen kann
und deswegen keine Variablen übergeben kann,
die dann mittles PHP in txt dateien geschrieben werden sollen
um sie dann wieder mit flash aus zu lesen

das php script funktioniert, wenn ich es teste

alles ist unter htdocs, und apache service läuft !

woran kanns liegen ?? an meinen Flash einstellungen oder an PHP??

GRUSS Oller

[StephanF]

ohne den AS-Code zu sehen, wie du PHP ansprichst, kann man da nix sagen

[oller_24]

ok logisch

das einfach konzept besteht aus nem swf nem php und ner txt

in flash Eingabetextfeld soll mit variable an php gesendet werden und dann schliesslich in txt .... mit flash auslesen kann ich ohne probleme... aber bei der variablenübergabe von flash zu php haperts... so

hab da mal was gegoogelt und vieles gefunden ging aber nie

zb AS...

loadVariablesNum("speichern.php3", 0);

und

loadVariablesNum("speichern.php3", 0, "POST");

dazu die speichern.php3:

PHP-Code:

<?
$datei_name = "speichern.txt";

if(fopen($datei_name,"r"))
{
    $datei = fopen($datei_name,"a+");
    fwrite($datei, "Name: ".$name."\n");
    fwrite($datei, "Nachricht: ".$inhalt."\n\n");
    fclose($datei);
}
else
{
    echo "speichern=nein";
}
?>

oller

[oller_24]

aber das problem besteht eigentlich darin, dass das php script gar nicht geöffnet oder angesprochen wird so dass gar nix übergeben werden kann,

hab mir die php logs angesehen.... aus flash geht da gar nix nur wenn ich php direkt öffne im browser zb localhost/speichern.php3

das problem sollte erst mal geklärt werden

oller

[StephanF]

guck dir mal das Beispiel an. Hier kannst Du sehen, wie man mit Flash PHP anspricht

[oller_24]

aber können wir bei flash, PHP und ner txt bleiben wäre mir lieber

weil ich gerne die inhalte aus txt auslesen würde wenn ich mal viel zeit hab werde ich mich mal wieder mit DB beschäftigen

[StephanF]

OK, dann wollen wir mal: (kleines Tut)
Hier das Ergebnis angucken.
Zuerst die Flashdatei, hier im Beispiel zwei Textfelder "namen_txt" mit Variable "namenVar" und "email_txt" mit Variable "emailVar", ein Button zum Senden "senden_btn" und ein Textfeld für die Meldungen "status_txt". Das AS:

PHP-Code:

//Ärger mit Umlauten vermeiden
System.useCodepage = true;
//
//Variablen Initialisierung
namenVar = "";
emailVar = "";
//Tabulator Reihenfolge
namen_txt.tabIndex = 1;
email_txt.tabIndex = 2;
//Erlaubte Zeichen
namen_txt.restrict = "a-z A-Z";
email_txt.restrict = "a-z A-Z 0-9 @.";
//Zeichenlänge
namen_txt.maxChars = 20;
email_txt.maxChars = 50;
//
//führende Leerzeichen aus Textfeldern entfernen
leerZeichenWeg = function (feld, txt) {
    while (txt.charAt(0) == " ") {
        txt = txt.slice(1);
    }
    trace(txt);
    feld.text = txt;
};
//Funktionen für den Sende Button
senden_btn.onRollOver = function() {
    this.t_txt.textColor = 0xFFFFFF;
};
senden_btn.onRollOut = function() {
    this.t_txt.textColor = 0xFF6600;
};
senden_btn.onRelease = senden_btn.onReleaseOutside = function () {
    //Funktion aufrufen
    formSenden();

};
formSenden = function () {
    //Alle Fehler auf 0 setzen
    var fehler:Number = 0;
    //führende Leerzeichen entfernen
    leerZeichenWeg(namen_txt, namenVar);
    leerZeichenWeg(email_txt, emailVar);
    //Textfeld für den Namen überprüfen
    if (namen_txt.text.length<2) {
        status_txt.textColor = "0xCCCCCC";
        status_txt.text = "Bitte einen Namen angeben.";
        fehler++;
    }
    //Textfeld für E-Mail überprüfen
    //geht noch ausführlicher und genauer
    if (email_txt.text.length<8) {
        status_txt.textColor = "0xCCCCCC";
        status_txt.text = "Keine gültige E-Mail.";
        fehler++;
    }
    if (fehler == 0) {
    //Wenn es keine Fehler gibt
    //mit dem Senden an PHP beginnen
    //
    //Die beiden folgenden Variablen
    //werden zum auswerten benötigt
    _global.abwarten = false;
    _global.erfolgreich = false;
    //
    //Hier eine kleine Funktion
    //wie lange wir auf eine Antwort 
    //von PHP warten wollen
        setTimeout(function () {
            //Sobald 3 Sekunden vorbei sind
            //wird die Funktion abwartenVorbei()
            //aufgerufen und abwarten auf true gesetzt
            abwarten = true;
            abwartenVorbei();
        }, 3000);
        //Der Text während des Wartens
        status_txt.textColor = "0xFFFFFF";
        status_txt.text = "Bitte warten, Daten werden gesendet";
        //
        //neue Objekt von LoadVars anlegen
        var export:LoadVars = new LoadVars();
        //
        //Sicherheitsabfrage an PHP, ob Daten auch wirklich von Flash kommen
        export.anfrageVonFlash = 1;
        //Übergabe der Werte aus den Textfeldern
        export.flaNamen = namenVar;
        export.flaEmail = emailVar;
        //
        var anPHP:LoadVars = new LoadVars();
        //Übergabe an an die PHP datei schreiben.php
        export.sendAndLoad("schreiben.php?"+new Date().getTime(), anPHP, "POST");
        anPHP.onLoad = function(erfolg:Boolean) {
            if (erfolg) {
                erfolgreich = true;
                //Wenn PHP die Variable eintragOK mit dem Wert 1 zurück sendet
                //dann war alles OK
                if (anPHP.eintragOK == 1) {
                    status_txt.textColor = "0xFFFFFF";
                    status_txt.text = ">> Eintrag war OK <<";
                }
            } 
        };
        //ENDE vanPHP.onLoad = function(erfolg:Boolean) {
    }
    //ENDE if (fehler == 0) {          
};
//Die Funktion zur Kontrolle
abwartenVorbei = function () {
    //Wenn die Wartezeit vorbei ist
    //und von PHP nix zurück kam
    //dann ist was faul
    if (abwarten == true && erfolgreich == false) {
        status_txt.textColor = "0xCCCCCC";
        status_txt.text = "PHP-Datei antwortet nicht.";
    }
}; 


und die php Datei schreiben.php

PHP-Code:

//Funktioniert nur, wenn von Flash gesendet
//klein bischen Sicherheit
//Hier muß aber noch wesentlich mehr an Sicherheit gemacht werden
if(isset($_POST[anfrageVonFlash])){    
    
    //Alle gesendeten POST Variablen umwandeln
    while (list($feld, $inhalt) = each ($_POST)) {
        $inhalt = trim($inhalt);
        //Tags entfernen
        //klein bischen Sicherheit
        $inhalt = strip_tags($inhalt);
        ${"var_".$feld} = $inhalt;
    }    

    $textdatei = fopen("namen.txt","a");
    fputs($textdatei,
    date("Y.m.d H:i:s", time()). ", ".$var_flaNamen.", ".$var_flaEmail."\n");
    fclose($textdatei);
    //Die Variable, auf die Flash wartet
    echo "&eintragOK=1&";
}//Ende if(isset($_POST[anfrageVonFlash])){ 


[oller_24]

bin grad von der arbeit heim werde es aber heute abend natürlich noch testen vielen dank erst mal für die hilfe

GRUSS Oller

[oller_24]

so ich hab alles so gemacht wie gesagt alles ist in htdocs apache läuft

antwort war wieder mal php datei antwortet nicht

hab swf als auch swf in html im browser geöffnet mit absolutem link zu lokalem server der link wäre dann:

http://localhost/TP_Test/TP_Test_01.html

bzw.

http://localhost/TP_Test/TP_Test_01.swf

geht nix aus flash ... was mache ich falsch ??

hier noch des zip im anhang.. könnte ich deine dateien mal haben fla und php ??

oller

[StephanF]

was sollen wir mit deiner zip, wo keine fla drinne ist

[oller_24]

hier die fla war ....schon etwas müde gestern

[StephanF]

Kann ich nicht öffnen, hab kein CS3 Flash, "nur" Flash 8

[oller_24]

sollte jetzt im flash 8 format sein

[StephanF]

Du hast eine schreibe.php, im AS willst du aber eine schreiben.php aufrufen.

[oller_24]

es geht!!!

na ja dann werd ich mal versuchen was nettes draus zu machen mit den neuen möglichkeiten, vielen dank schon mal

und wenns wieder fragen gibt schreib ich dir .... dauert bestimmt ned lange

grüsse oller